[求助]如何批量删除一个文件夹下所有Word文件的页眉和页脚?
请各位帮助偶一下,如何批量去除一个文件夹下所有Word文件的页眉和页脚?用VBA也可以。谢谢。
QUOTE:
以下是引用acer_peri在2007-12-24 20:25:36的发言:
请各位帮助偶一下,如何批量去除一个文件夹下所有Word文件的页眉和页脚?用VBA也可以。谢谢。
请参考:
'* +++++++++++++++++++++++++++++
'* Created By SHOUROU@ExcelHome 2007-12-25 18:34:02
'仅测试于System: Windows NT Word: 11.0 Language: 2052
'№ 0291^The Code CopyIn [ThisDocument-ThisDocument]^'
'* -----------------------------
Option Explicit
Sub Example() '此代码功能为列出指定文件夹中所有选取的WORD文件全路径名
Dim myDialog As FileDialog, oDoc As Document, oSec As Section
Dim oFile As Variant, myRange As Range
On Error Resume Next
'定义一个文件夹选取对话框
Set myDialog = Application.FileDialog(msoFileDialogFilePicker)
With myDialog
.Filters.Clear '清除所有文件筛选器中的项目
.Filters.Add "所有 WORD 文件", "*.doc", 1 '增加筛选器的项目为所有WORD文件
.AllowMultiSelect = True '允许多项选择
If .Show = -1 Then '确定
For Each oFile In .SelectedItems '在所有选取项目中循环
Set oDoc = Word.Documents.Open(FileName:=oFile, Visible:=False)
For Each oSec In oDoc.Sections '文档的节中循环
Set myRange = oSec.Headers(wdHeaderFooterPrimary).Range
myRange.Delete '删除页眉中的
myRange.ParagraphFormat.Borders(wdBorderBottom).LineStyle = wdLineStyleNone '段落下边框线
Next
oDoc.Close True
Next
End If
End With
End Sub
'----------------------
我运行了您给的VBA,好像只去了页眉。您能改进一下,把页脚也去了吗?
如果要是能一次选择嵌套文件夹下的所有文件就更好了,谢谢您!
QUOTE:
以下是引用acer_peri在2007-12-25 22:23:39的发言:
我运行了您给的VBA,好像只去了页眉。您能改进一下,把页脚也去了吗?
如果要是能一次选择嵌套文件夹下的所有文件就更好了,谢谢您!
把页脚也删除的代码如下:
'* +++++++++++++++++++++++++++++
'* Created By SHOUROU@ExcelHome 2007-12-26 6:12:17
'仅测试于System: Windows NT Word: 11.0 Language: 2052
'№ 0292^The Code CopyIn [ThisDocument-ThisDocument]^'
'* -----------------------------
Option Explicit
Sub Example() '此代码功能为列出指定文件夹中所有选取的WORD文件全路径名
Dim myDialog As FileDialog, oDoc As Document, oSec As Section
Dim oFile As Variant, myRange As Range
On Error Resume Next
'定义一个文件夹选取对话框
Set myDialog = Application.FileDialog(msoFileDialogFilePicker)
With myDialog
.Filters.Clear '清除所有文件筛选器中的项目
.Filters.Add "所有 WORD 文件", "*.doc", 1 '增加筛选器的项目为所有WORD文件
.AllowMultiSelect = True '允许多项选择
If .Show = -1 Then '确定
For Each oFile In .SelectedItems '在所有选取项目中循环
Set oDoc = Word.Documents.Open(FileName:=oFile, Visible:=False)
For Each oSec In oDoc.Sections '文档的节中循环
Set myRange = oSec.Headers(wdHeaderFooterPrimary).Range
myRange.Delete '删除页眉中的内容
myRange.ParagraphFormat.Borders(wdBorderBottom).LineStyle = wdLineStyleNone '段落下边框线
Set myRange = oSec.Footers(wdHeaderFooterPrimary).Range
myRange.Delete '删除页脚中的内容
Next
oDoc.Close True
Next
End If
End With
End Sub
'----------------------
遍历所有文件夹及其子文件夹的代码相对要复杂一些,论坛上有,自己搜索一下,如果没有几个子文档夹,多运行一二次就行了。你的这个删除所有Word文件页眉页脚的要求很奇怪。
应用为王——巧妙批量修改word页眉页脚
在word中可以添加或者修改页眉页脚,但是在实际操作中,需要给很多个文档添加或修改相同的页眉页脚时,该怎么办呢?
下面为大家介绍一个解决这个难
非常实用的工具——DOC文件页眉页脚修改器。
将要修改相同页眉或页脚的文档全部集中存在一个文件夹下,然后运行软件,如图:
页眉可以是图片,也可以是文字,如果让页眉是图片,则勾选“图片”,点击“加载”选择欲添加到页眉的图片。
如果要添加页眉的文字,就勾选“增加页眉”下的“文字”,在文字框内输入欲添加的页眉文字,勾选“居左”、“居中”、“居右”三种位置之一。
添加页脚文字,而勾选“页脚”,在文字框内输入页脚文字。在“文件所在路径(文件夹名称)下点击“浏览”选择文件所在的文件夹。然后点击“批量修改按”钮即可。
小提示:试用过程来看,“修改完毕”的对话框出现的时间比真正成功批量转换的时间要晚,实际上软件已经早把文档修改好了。所以,在修改过程中,打开文档,如果都成功添加好了,直接退出软件即可。另外,如果要批量删除页眉页脚,则请保持软件里所有页眉页脚的选项为空白再执行批量修改操作即可。
下载地址:http://work.newhua.com/cfan/200823/docfile.rar